题解 | #多bit MUX同步器#

`timescale 1ns/1ns

module mux(
	input 				clk_a	, 
	input 				clk_b	,   
	input 				arstn	,
	input				brstn   ,
	input		[3:0]	data_in	,
	input               data_en ,

	output reg  [3:0] 	dataout
);

// 题目要求对输入的信号进行同步，需要将a时钟下的输入信号和使能信号同步到b时钟下
//所以首先需要对a时钟下的信号进行打一拍，然后对使能信号在b时钟下进行打两拍操作，因为在输出端没有使能的输出，所以同步操作只需同步使能信号

reg  [3:0]	data_reg;	//暂存数据

reg data_en_a, data_en_b0, data_en_b1;

//1.数据暂存

//在原时钟a下进行一拍寄存，对于输入进行寄存是很常见的方法，主要是去除毛刺等，做一个本时钟域的同步

always@(posedge clk_a or negedge arstn) begin
    if(!arstn)
        data_reg <= 0;
    else
        data_reg <= data_in; 
end

//2. 使能信号打拍
// data_en信号在A时钟域用一个D触发器暂存，然后打两拍传输到B时钟域

always@(posedge clk_a or negedge arstn)begin
	if(!arstn)
		data_en_a <= 0;
	else
		data_en_a <= data_en;
end

always@(posedge clk_b or negedge brstn)begin
	if(!brstn)begin
		data_en_b0 <= 0;
		data_en_b1 <= 0;
	end
	else begin
		data_en_b0 <= data_en_a; //打两拍
		data_en_b1 <= data_en_b0;
	end
end

// 3.MUX选择器
always@(posedge clk_b or negedge brstn)begin 
	if(!brstn)
		dataout <= 0;
	else
		dataout <= data_en_b1? data_reg : dataout;
end

endmodule