销售需求丨动态坐标（修订）

学过的东西如果不进行迅速的巩固，那么学习就是为了更快的遗忘。

之前呢，白茶分享了如何制作动态数据的方法，咱们来继续研究，动态坐标轴。有时候经常能遇到，说想在一个可视化插件中能够灵活的切换维度，就像下面这个动图一样：

那么这个效果该怎样进行呢？跟着白茶的思路走。

这是之前白茶使用的示例数据，这次依然是选择它。

建立基本的度量值：

销售金额 =
SUMX ( '销售明细', '销售明细'[销售数量] * RELATED ( '产品表'[销售价] ) )

这是我们的准备工作。

建立动态维度的难点主要有两个，一个是创建新的维度表，一个是将新的维度与原有的数据建立关系。

一、合并维度

已知我现在有两个维度，一个是商品名称，一个是分店维度，我现在想将二者合并：

要达到图上的这种效果，该如何进行呢？还记得白茶在之前曾经提到过创建表的那一期么？先上代码，再解释含义：

名称与分店维度 =
VAR BC1 =
    SELECTCOLUMNS (
        ADDCOLUMNS ( DISTINCT ( '分店表'[分店名] ), "名称与分店", "分店" ),
        "名称与分店", [名称与分店],
        "具体内容", [分店名]
    )
VAR BC2 =
    SELECTCOLUMNS (
        ADDCOLUMNS ( DISTINCT ( '产品表'[商品名称] ), "名称与分店", "商品名称" ),
        "名称与分店", [名称与分店],
        "具体内容", [商品名称]
    )
RETURN
    UNION ( BC1, BC2 )

结果如下：

这里涉及到的代码比较多，白茶慢慢说（BC2就不说了，只说BC1）：

DISTINCT在这里的作用是去除重复值，生成一个分店维度的单列表。

ADDCOLUMNS在这里的作用是根据DISTINCT生成的表添加一列，名为“名称与分店维度”，并且列的内容都是“分店”。

SELECTCOLUMNS在这里的作用是将ADDCOLUMNS生成的表格，重新命名。

（这里其实可以省略，但是白茶觉得加上的话是一个双保险，可以避免UNION顺沿的时候出现不可预知的错误。）

同理，BC2是生成一个“名称”的表格。

UNION起连接作用，将两次生成的表格合并。

二、建立关系

这里需要说一下另一个函数：TREATAS函数。

语法=
TREATAS(table_expression,<column>[,<column>[,<column>[,…]]])

白茶觉得TREATAS最大的作用就是强行建立虚拟关系，进行调用。需要注意的是微软的描述强调的是筛选作用，主要是筛选，当两个表没有联系时使用TREATAS最恰当。

可以使用IF或者SWITCH函数。

编写如下代码：

第一种写法：

SWITCH写法动态坐标 =
VAR BC3 =
    TREATAS ( VALUES ( '名称与分店维度'[具体内容] ), '产品表'[商品名称] )
VAR BC4 =
    TREATAS ( VALUES ( '名称与分店维度'[具体内容] ), '分店表'[分店名] )
RETURN
    SWITCH (
        TRUE (),
        SELECTEDVALUE ( '名称与分店维度'[名称与分店] ) = "商品名称", CALCULATE ( [销售金额], BC3 ),
        SELECTEDVALUE ( '名称与分店维度'[名称与分店] ) = "分店", CALCULATE ( [销售金额], BC4 ),
        BLANK ()
    )

第二种写法：

IF写法动态坐标 =
VAR BC3 =
    TREATAS ( VALUES ( '名称与分店维度'[具体内容] ), '产品表'[商品名称] )
VAR BC4 =
    TREATAS ( VALUES ( '名称与分店维度'[具体内容] ), '分店表'[分店名] )
RETURN
    IF (
        SELECTEDVALUE ( '名称与分店维度'[名称与分店] ) = "商品名称",
        CALCULATE ( [销售金额], BC3 ),
        IF (
            SELECTEDVALUE ( '名称与分店维度'[名称与分店] ) = "分店",
            CALCULATE ( [销售金额], BC4 ),
            BLANK ()
        )
    )

结果如下图：